Subversion Repositories svnkaklik

set terminal png

set key off

set grid

f(x)=k*x+q

g(x)=p/x+t

#energeticka kalibrace

fit f(x) "kalibrace.txt" using 1:2 via k,q

set output "kalibrace.png"

set xlabel "Číslo kanálu"

set ylabel "Energie [keV]"

plot "kalibrace.txt" using 1:2 with points, f(x)

#set xrange [0:2000] 

# energeticke rozliseni 

fit g(x) "kalibrace.txt" using ($2):(($3)/($2)) via p,t

set output "kalibrace_sigma.png"

set xlabel "Energie [keV]"

set ylabel "S [-]"

plot "kalibrace.txt" using 2:($3/$2) with points, g(x)

set xrange [0:1800] 

set output "pozadi.png"

set xlabel "Energie [keV]"

set ylabel "Intenzita [Imp]"

plot "./data2/pozadi.txt" using (f($1)):2 with points

set key top

set xrange [0:300] 

set output "Am241.png"

plot "./data2/Am.txt" using (f($1)):2 with points title "Am"

set xrange [0:800] 

set yrange [0:8000] 

set output "Ba133.png"

plot "./data2/Ba.txt" using (f($1)):2 with points title "Ba"

set xrange [0:1800] 

set yrange [0:500] 

set output "Co60.png"

plot "./data2/Co.txt" using (f($1)):2 with points title "Co"

set yrange [0:3000] 

set output "Cs137.png"

plot "./data2/Cs.txt" using (f($1)):2 with points title "Cs"

set key off

set yrange [0:600] 

set output "neznamy.png"

plot "./data2/neznamy.txt" using (f($1)):2 with points title "Uknown"

set key under

#set autoscale x

set autoscale y

set xrange [0:4]

#set logscale y

c1(x)=I1*exp(u1*x)

c2(x)=I2*exp(u2*x)

c3(x)=I3*exp(u3*x)

I1=10000

I2=10000

I3=10000

fit [0:2] c1(x) "./stineni.txt" using ($1):2 via I1,u1

fit [0:2] c2(x) "./stineni.txt" using ($1):3 via I2,u2

fit [0:2] c3(x) "./stineni.txt" using ($1):4 via I3,u3

set output "stineni.png"

plot "./stineni.txt" using ($1):2:5 with errorbars title "1332,492 keV", c1(x), "" using ($1):3:6 with errorbars title "1173,228 keV",c2(x)

set xrange [0:4]

set yrange [150000:200000]

set output "stineni2.png"

plot "./stineni.txt" using ($1):4:7 with errorbars title "661,657 keV", c3(x)

set autoscale y

#set autoscale x

set xrange [100:1500]

set output "utlum.png"

plot "./utlumy.txt" using (f($1)):5 with points title "0 mm", "" using (f($1)):10 with points title "2 mm", "" using (f($1)):15 with points title "3,5 mm"

set output "utlum0.png"

plot "./utlumy.txt" using (f($1)):2 with points title "0 mm pozadi", "" using (f($1)):4 with points title "0 mm zarice"

set output "utlum2.png"

plot "./utlumy.txt" using (f($1)):7 with points title "2 mm pozadi", "" using (f($1)):9 with points title "2 mm zarice"

set output "utlum35.png"

plot "./utlumy.txt" using (f($1)):12 with points title "3,5 mm pozadi", "" using (f($1)):14 with points title "3,5 mm zarice"

print u1

print u2

print u3